Keith Devens .com

My priest's macros

I recently set up a whole bunch of macros for my priest. Figured I'd put them here for my own future reference, and in case anyone else wants to copy them.

In general, since priests can cast heal spells and damage spells, but you can't damage friends or heal enemies, you get a modal interface. Many of my macros enable the same button to be used for one action if targeting a friendly, and another action if targeting a hostile. Another goal was to enable mouseover on everything.

"Abolish"

/cast [mod:SELFCAST, target=player] [target=mouseover, exists] [] Abolish Disease


"Dispel" (hold shift for mass dispel)

/cast [mod:shift] Mass Dispel; [mod:SELFCAST, target=player] [target=mouseover, exists] [] Dispel Magic


"BUFF" (one button buff!)

/cast [nomod] Power Word: Fortitude; [mod:alt,mod:shift,mod:ctrl] Prayer of Shadow Protection; [mod:alt,mod:shift] Shadow Protection; [mod:alt] Inner Fire; [mod:shift,mod:ctrl] Prayer of Spirit; [mod:shift] Divine Spirit; [mod:ctrl] Prayer of Fortitude


Note I had to use [mod:alt] there instead of [mod:SELFCAST] because the macro inched over 255 characters.

"Flash/SWP"

/cast [target=mouseover,help,mod:shift][help,mod:shift]Binding Heal;[mod:alt,target=player][target=mouseover,help][help]Flash Heal;[target=mouseover,harm,mod:shift][harm, mod:shift]Vampiric Touch;[target=mouseover,harm][harm]Shadow Word: Pain;Flash Heal


Flash heal on friend, shadow word pain on an enemy. Hold shift for binding heal on a friend, hold shift for vampiric touch (if you have it) on an enemy.

"Greater heal"

/cast [mod:SELFCAST,target=player] [target=mouseover,help] [help] [] Greater Heal


Greater heal that works with mouseover.

"Holy nova"

/cast [nocombat] Holy Nova(Rank 1); Holy Nova


Casts rank 1 holy nova if you're not in combat. Super helpful for unstealthing rogues/druids without blowing lots of mana on max rank holy nova.

"Mind flay"

/cast [nochanneling:Mind Flay] Mind Flay


Keeps you from clipping your mind flay.

"PoH/MB/Rez"

/cast [harm] Mana Burn; [help, dead] [mod:shift] Resurrection; [help,nodead] [] Prayer of Healing;


On an enemy target, mana burns. If you target a friendly, casts prayer of healing. If your target is friendly and dead, or if you hold shift (for the times when people release), casts resurrection.

"PoM"

/cast [mod:ctrl]Mind Vision;[mod:SELFCAST,target=player][target=mouseover,help][help]Prayer of Mending;[target=mouseover,harm,mod:shift][harm,mod:shift]Mind Soothe;[target=mouseover,harm][harm]Mind Control;Prayer of Mending


Enemy: mind control, friend: prayer of mending. If you hold shift, does mind soothe. Works with mouseover, selfcast, etc.

"PWS/Shoot"

/cast [harm, nomod] Shoot; [mod:SELFCAST, target=player] [target=mouseover, help] [] Power Word: Shield


Power word: shield on a friend, wand shoot at an enemy.

"Renew/SWD"

/cast [mod:SELFCAST, target=player] [target=mouseover, help] [help] Renew; [target=mouseover, harm] [harm] Shadow Word: Death; Renew


Friendly: renew, enemy: shadow word: death.

"Shackle"

/clearfocus [mod:alt] [target=focus,dead]
/focus [target=focus,noexists]
/cast [target=focus] Shackle Undead


Typical shackle focus macro.

"Smite/HF"

/cast [mod:SELFCAST, target=player] [target=mouseover,help] [help] Greater Heal(Rank 2); [mod:shift] Holy Fire; Smite


Since holy fire is used rarely, I just stuck it on my smite button. Just hold shift. Also, since that button wasn't doing anything for friendly targets, I put a low rank of greater heal on there too.